module _c06418l;	flag '-r0';
title '
CAMAC 064 V7.3                                       R. J. DUCAR
06418L.DAT                                           3-15-96

Converted to ABEL using TA'

c06418l device 'F153';


"Pin definitions

B7	pin  1;
B6	pin  2;
B5	pin  3;
B4	pin  4;
B3	pin  5;
B2	pin  6;
B1	pin  7;
B0	pin  8;
E	pin  9;
GND	pin 10;
CLR	pin 11;
P8	pin 12;
P7	pin 13;
P6	pin 14;
P5	pin 15;
P4	pin 16;
P3	pin 17;
P2	pin 18;
P1	pin 19;
VCC	pin 20;

equations

P1 = !E & !B7 & !B6 & !B5 & B4 & !B3 & !B2 & !B1 & B0 # !CLR;	"11 CLR

P2 = !E & !B7 & !B6 & !B5 & B4 & !B3 & !B2 & B1 & CLR		"12 13
   # !E & !B7 & !B6 & !B5 & B4 & !B3 & B2 & CLR			"14 15 16 17
   # !E & !B7 & !B6 & !B5 & B4 & B3 & !B2 & !B1 & B0 & CLR	"19
   # !E & !B7 & !B6 & !B5 & B4 & B3 & B2 & !B1 & !B0 & CLR;	"1C

P3 = !E & !B7 & !B6 & !B5 & !B4 & B3 & !B2 & !B1 & !B0 & CLR	"08
   # !E & !B7 & !B6 & !B5 & B4 & !B3 & !B2 & B1 & CLR		"12 13
   # !E & !B7 & !B6 & !B5 & B4 & !B3 & B2 & CLR			"14 15 16 17
   # !E & !B7 & !B6 & !B5 & B4 & B3 & !B2 & !B1 & B0 & CLR	"19
   # !E & !B7 & !B6 & !B5 & B4 & B3 & B2 & !B1 & !B0 & CLR;	"1C

!P4 = !E & !B7 & !B6 & !B5 & B4 & !B3 & !B2 & !B1 & B0 & CLR	"11
    # !E & !B7 & !B6 & !B5 & B4 & !B3 & !B2 & B1 & CLR		"12 13
    # !E & !B7 & !B6 & !B5 & B4 & !B3 & B2 & !B1 & CLR		"14 15
    # !E & !B7 & !B6 & !B5 & B4 & !B3 & B2 & B1 & !B0 & CLR	"16
    # !E & !B7 & !B6 & !B5 & B4 & B3 & !B2 & !B1 & B0 & CLR	"19
    # !E & !B7 & !B6 & !B5 & B4 & B3 & B2 & !B1 & !B0 & CLR;	"1C

!P5 = !E & !B7 & !B6 & !B5 & B4 & !B3 & B2 & B1 & B0 & CLR;	"17


"DESCRIPTION:  This PAL decodes TCLK events for V7.3 of the CAMAC
"              064 module.  It generates the gates for the Booster
"	      High Level RF Programs.  Gates 1 and 2 are identical,
"              except that Gate 2 will come on early with $08.
"              It also generates certain TCLK events which drive 
"              Gated Outputs #1 and #2 to control the applied rf to
"              the BBDLY NIM module.
"
"              Gate 1 Set:  $12, $13, $14, $15, $16, $17, $19, $1C      (P2)
"
"              Gate 2 Set:  $08, $12, $13, $14, $15, $16, $17, $19, $1C (P3)
"
"              Gate 1 and 2 Reset: $11                                  (P1)
"
"              Gated Output #1: $11, $12, $13, $14, $15, $16, $19, $1C  (P4)
"
"              Gated Output #2: $17                                     (P5)
"
"	      Names:  Gate 1 - B:ANCSG
"	              Gate 2 - B:BIASG
"
"
"              Refer [DUCAR.DOC]CMC064.VER for additional information 
"              related to V7.3.

end _c06418l