module _c28903;
title 'C289 Qualifier Kluge CAMAC function decoder
19-May-1999
Checksum: 3E9F
Fuse #:   0495'

c28903 device 'F173';

"Pin definitions

F16,F8,F4,F2,F1		pin  1,2,3,4,5;		"Function codes
A8,A4,A2,A1		pin  6,7,8,10;		"Subaddress
N,Z,S1,S2		pin  9,14,11,13;	"Control lines
DF6,DF1			pin 15,16;		"Decoded functions
CLR,PUC			pin 17,22;		"Clear, Power up clear
QX			pin 18;			"Q and X response
GND,VCC			pin 12,24;		"Power and ground

"Macros
func = [!F16,!F8,!F4,!F2,!F1];
addr = [!A8,!A4,!A2,!A1];

equations

!QX = !N & (func==1) & (addr==0) & PUC	"F(1) A(0)
    # !N & (func==6) & (addr==0) & PUC	"F(6) A(0)
    # !N & (func==7) & (addr==0) & PUC	"F(7) A(0)
    # !N & (func==9) & (addr==0) & PUC;	"F(9) A(0)

!DF6 = !N & (func==6) & (addr==0) & PUC;	"F(6) A(0)

!DF1 = !N & (func==1) & (addr==0) & PUC;	"F(1) A(0)

!CLR = !N & (func==9) & (addr==0) & S1 & PUC	"F(9) A(0) S1
     # !Z & !S2	
     # !PUC;


"DESCRIPTION:  This PAL provides the NAF decoding for the CAMAC
"              289 module.  A F(7)A(0) code for a 
"              no-op read is included in the QX term.  

end _c28903